﻿// create delta structure
Process V[SalesOrderUpd] = so_create_delta_structure V[SalesOrder] V[SalesOrderUnchanged]

// any changes ?
if not V[SalesOrderUpd]
  Message "W: No data changed" -statusline
  Leave
endif


// SAP message
CreateStructure V[msg] type message code  target

// update sales order
CallVB guinet.odata.update _
  service:="&V[so_service] ('&V[so_selorder]')" _
  values:="SalesOrderUpd" _
  options:="-isDate.RequestedDeliveryDate,-isBoolean.CompleteDeliveryIsDefined" _
  etag:="&V[so_etag]" _
  newetag:="so_newetag" _
  message:="msg"

// check for update conflict (English logon)
Set V[temp] "&V[msg.message]" _
  regex="^The sales document was updated by"

if Q[ok]
  Message "&V[msg.message]" && _
    "\n\nPlease select the sales order again" && _
    " to view the updated content," && _
    " re-enter your changes and save again." _
    type="E" _
    title="Update failed"
else  
  
  // display SAP message
  Message "&V[msg.message]" type="&V[msg.type]" -statusline 
  
endif



// error ?
if V[msg.type=E]
  //indicate: error in update 
  Set V[SalesOrders._statusicon.&V[so_selindex]] "@8O@" 
else
  
  // update table on success
  UpdateRow V[SalesOrderUpd] table=V[SalesOrders] index=&V[so_selindex]
  
  // update content
  Set V[SalesOrderUnchanged] "&V[SalesOrder]"
  
  //indicate: changed
  Set V[SalesOrders._statusicon.&V[so_selindex]] "@01@"
  
  // set new etag for next update
  Set V[so_etag] "&V[so_newetag]"  
endif



Return 