﻿
if not V[VA05_Quick_Change]
  PushButton (toolbar) "Quick Change Mode" process="so_toggle_va05_mode.txt"
  Leave
endif

PushButton (toolbar) "SAP Standard" process="so_toggle_va05_mode.txt"


// remove existing elements
del (0,0) (50,200) 
del P[/25]      	// Display Variants
del P[/17]      	// Get...
del P[/11]        // Save
del P[/86]      	// Execute and Print  

Text P[/8] "@15\QSelect Orders@Select Orders"
on "/8" process="so_read_orders.txt"


Title "Sales Orders: Quick Change"

// OData service selection (demo mode)
// The app can use a v2 or a v4 SAP OData service 
// Default is v2
if not  V[so_serviceversion]
  Set  V[so_serviceversion]  "v2"
endif

if V[so_serviceversion=v2]
  Set V[so_service] "sap/opu/odata/sap/API_SALES_ORDER_SRV/A_SalesOrder"
endif

if V[so_serviceversion=v4]
  Set V[so_service] "sap/opu/odata4/iwbep/all/srvd/sap/c_salesordermanage_sd/0001/SalesOrderManage"
endif

// Switch v2/v4 via a HelpView
Image (toolbar) "help.gif" viewHelp="so_help.html"

Box	(0,1)	(7,116)	"Sales Order Selection"
InputField	(1,2)	"Customer"		(1,24)	size=10	name="filter_customer"  -upperCase  techName="VBAK-KUNNR"
InputField	(2,2)	"Order Number"	(2,24)	size=10	name="filter_salesorder"	techName="VBAK-VBELN" -numerical
InputField	(3,2)	"Cust. Reference contains"	(3,24)	size=30	name="filter_reference"
InputField	(4,2)	"Order Date"	(4,24)	size=10	name="filter_date1"	-date
InputField	(4,38)	"To"			(4,44)	size=10	name="filter_date2"	-date
InputField	(5,2)	"Net Amount"	(5,24)	size=10	name="filter_amount1"	-date
InputField	(5,38)	"To"			(5,44)	size=10	name="filter_amount2"	-date
InputField	(6,2)	"Currency"	(6,24)	size=5	name="filter_currency"

Table (8,1) (22,117) name="SalesOrders" title="Sales orders (&V[SalesOrders.rowcount])"
Column " "   size=4 name="_statusicon" -pushButton process="so_select_order.txt"
Column "Order" size=10 name="SalesOrder" -readOnly
Column "Date" size=10 name="SalesOrderDate" -readOnly
Column "Type" size=4 name="SalesOrderType" -readOnly
Column "Customer" size=10 name="SoldToParty" -readOnly
Column "Cust. Reference" size=30 name="PurchaseOrderByCustomer" -readOnly
Column "Req. Deliv. Date" size=14 name="RequestedDeliveryDate" -readOnly  
Column "Currency" size=10 name="TransactionCurrency" -readOnly 
Column "Net Amount" size=15 name="TotalNetAmount" -readOnly -alignRight

// selected order
if V[so_selorder]
  
  Offset (23,0)
  Box  (0,1) (6,116) " Order Nr. &V[SalesOrder.SalesOrder] from &V[SalesOrder.SalesOrderDate]," && _
    " &V[Customer.CustomerFullName]"
  
  InputField (2,3)	"Req.Deliv.Date"	(2,20) -date name="SalesOrder.RequestedDeliveryDate"
  CheckBox	 (2,34)	"Complete Deliv."	name="SalesOrder.CompleteDeliveryIsDefined"
  
  InputField (3,3)	"Cust.Reference"	(3,20)	size=35	name="SalesOrder.PurchaseOrderByCustomer"
  
  PushButton (5,3)	"Save changes" process="so_update_order.txt" size=(1,17)
  
endif