﻿// Define table name for simplicity
Set V[va01_pdf_tabname] "SAPMV45A_TCTRL_U_ERF_AUFTRAG"

// Use TA as default
Set [RV45A-TXT_AUART] "TA"

// Switch to order data and write to fields
Screen SAPMV45A.4001
  Set [KUAGV-KUNNR] "&V[va01_pdf_soldacct]"
  Set [KUWEV-KUNNR] "&V[va01_pdf_shipacct]"
  Set [VBKD-BSTKD] "&V[va01_pdf_cref]"
  
  // Write items to table 
  Set V[va01_pdf_abs_item] 1
  Enter P[T\02]
  
  label new_screen
Screen SAPMV45A.4001
  GetTableAttribute T[&V[va01_pdf_tabname]] _
    lastVisibleRow="va01_pdf_lv" _
    firstVisibleRow="va01_pdf_abs_item"
  
  Set V[va01_pdf_wrt_item] 1
  
  label wrt_item 
  if V[va01_pdf_abs_item>&V[va01_pdf_itemstab.rowcount]]  
    goto end
  endif
  // Scroll down if end of writable area reached
  if V[va01_pdf_abs_item>&V[va01_pdf_lv]] 
    Enter "/scrollToLine=&V[va01_pdf_abs_item]" table="T[&V[va01_pdf_tabname]]"    
    goto new_screen
  endif   
  // Go to next empty row
  if not cell[&V[va01_pdf_tabname],RV45A-MABNR,&V[va01_pdf_wrt_item]=]
    Set V[va01_pdf_abs_item] "&V[va01_pdf_abs_item]" + 1
    Set V[va01_pdf_wrt_item] "&V[va01_pdf_wrt_item]" + 1
    goto wrt_item
  endif
  
  // Translate unit
  CreateTable V[va01_pdf_unit] unit
  Set V[table] "T006A"
  Set V[condition] "MSEHI = ( SELECT MSEHI FROM T006A WHERE SPRAS = '&V[va01_pdf_chk_lang.lang.1]' AND MSEH3 = '&V[va01_pdf_itemstab.unit.&V[va01_pdf_abs_item]]' ) AND SPRAS = '&V[_language]'"
  Set V[fields] "MSEH3"
  
  // select data from table T006A
  Call /guixt/dbselect cache="session" _
    export.table="table" _
    export.condition="condition" _
    export.fields="fields" _
    import.values="va01_pdf_unit"
  
  // write row
  Set cell[&V[va01_pdf_tabname],RV45A-MABNR,&V[va01_pdf_wrt_item]] "&V[va01_pdf_itemstab.id.&V[va01_pdf_abs_item]]"
  Set cell[&V[va01_pdf_tabname],VBAP-ARKTX,&V[va01_pdf_wrt_item]] "&V[va01_pdf_itemstab.text.&V[va01_pdf_abs_item]]"
  Set cell[&V[va01_pdf_tabname],RV45A-KWMENG,&V[va01_pdf_wrt_item]] "&V[va01_pdf_itemstab.qty.&V[va01_pdf_abs_item]]"
  Set cell[&V[va01_pdf_tabname],VBAP-VRKME,&V[va01_pdf_wrt_item]] "&V[va01_pdf_unit.unit.1]"
  
  Set V[va01_pdf_abs_item] "&V[va01_pdf_abs_item]" + 1
  Set V[va01_pdf_wrt_item] "&V[va01_pdf_wrt_item]" + 1  
  goto wrt_item
  
  label end
  // scroll table to first line
  Enter "/scrollToLine=1" table="T[&V[va01_pdf_tabname]]"
  
  
  