Purpose
You want to call up a transaction and skip the first screen, setting some field values into the initial screen.

This can be achieved with an InputScript, but for simple cases there is an alternative way, namely a SAP GUI built-in feature which allows us to specify field values as part of the OK-Code string.

Solution
Use an OK-Code of the following stucture:

/*xxxx [FNAME1]=value1; [FNAME2]=value2; ... DYNP_OKCODE=zzzz

(see examples below)

Here

  • xxxx ist the transaction code
  • FNAME1, FNAME2, .. are SAP field names such as VBAK-VBELN (technical name in SAP dynpro, displayed with F1->Technical information)
  • value1, ... value2 are the corresponding fields values to be set in the initial screen
  • zzzz is the function code which you wish to execute on the initial screen.
    If DYNP_OKCODE= is not specified,  the "Enter" key is executed

Remarks

  • A GuiXT script for the hidden first screen is not processed.
  • There is no way to set field values or perform actions on the next (second) screen with this mechanism; use an InputScript if this is needed.
  • You can combine this notation with /O, starting a  new mode.
    See Example 5 below.

Example 1
 GuiXT 

Pushbutton (toolbar) "Cash sale" "/*VA01 VBAK-AUART=CS"

Example 2
 GuiXT 

Pushbutton (toolbar) "Create repair order" _
         "/*IW31 AUFPAR-PM_AUFART=PM02; CAUFVD-IWERK=1000"


Example 3
GuiXT 

Pushbutton (toolbar) "Display document flow" _
      "/*VA03 VBAK-VBELN=&V[aufnr]; DYNP_OKCODE=IFLU"


Example 4 (in InputScript)
GuiXT 

Screen xxxxx.nnn
 Enter "/*VA03 VBAK-VBELN=&V[aufnr]; DYNP_OKCODE=IFLU"


Example 5
 GuiXT 

Pushbutton (toolbar) "Display document flow" _
      "/O*VA03 VBAK-VBELN=&V[aufnr]; DYNP_OKCODE=IFLU"

Components
InputAssistant