Ziel
Sie möchten eine S10 Anwendung erstellen, mit der der Benutzer Codes (Barcodes, QR-Codes etc.) einscannen kann.
Die erkannten Daten aus dem Code sollen automatisch weiterverarbeitet werden.
Mobile Geräte bieten eine Reihe an neuen Anwendungsmöglichkeiten durch den Zugriff auf die Kamera, Sensoren und so weiter.
Zum Scannen von Barcodes existieren JavaScript Bibliotheken, die Sie sehr einfach einbinden und verwenden können.
Implementierung
In der Regel wird in einem bestimmten S10-View im HTML Code die JavaScript-Bibliothek eingebunden, die das Scannen von Barcodes implementiert.
Wir verwenden im folgenden Beispiel den HTML5 QR Code scanner ,
den wir mit folgender Zeile einbinden:
Es wird nun zunächst ein neues Objekt erstellt und der Scanner gestartet. Zudem wird definiert was passieren soll, wenn der Scanner erfolgreich einen Code erkannt hat.
In diesem Fall wird der erkannte Text in ein Eingabefeld gesetzt. Dies kann ein S10 InputField sein, das heißt, der Inhalt der Variablen steht dann auch in der ABAP Klasse zur Verfügung.
JavaScript
// Start the scanner
var html5QrcodeScanner = new Html5QrcodeScanner(
"reader", { fps: 10, qrbox: 250 });
html5QrcodeScanner.render(onScanSuccess);
// The scanner recognized a code
function onScanSuccess(decodedText, decodedResult) {
// Put the recognized text of the code in an input field
document.getElementById('scan_result').value = decodedText;
// Needed to synchronize the data
S10Enter();
}
Die weitere Verarbeitung der Daten kann auf unterschiedliche Weise erfolgen:
1. Die erkannten Daten aus dem Code werdem dem Benutzer nur angezeigt und nicht weiter verabreitet
2. Die Daten werden automatisch durch eine JavaScript Methode verarbeitet, z.B. das Aufteilen in einzelne Felder aus einem Gesamttext
3. Die Verarbeitung findet in einer ABAP Methode statt.
HTML
<!-- Target area for the scanner-->
<div style="width:100%;height:35%;" id="reader"></div>
<!-- Normal S10 input field-->
<input class="input" id="scan_result" name="scan_result" type="text">
<!-- Hidden s10 field triggering JavaScript method on value change-->
<input class="input" name="scan_result" type="hidden"
onchange="parse_scan_result(this.value);">
<!-- Hidden s10 field triggering ABAP method on value change-->
<input class="input" name="scan_result" type="hidden"
onchange="S10Apply('parse_scan_result'); ">
Beispiel: Warenausgang buchen
Mit dieser S10 Anwendung kann ein Anwendunger mit seinem mobilen Gerät einen QR-Code scannen der folgende Daten enthält:
Belegnummer einer Ausliferung, Materialnummer, Position in Lieferung und Liefermenge.
Wird ein Code erkannt und die Daten eingelesen, kann er anschließend direkt die Buchung des Warenausgangs
im SAP System anstoßen.
ABAP Programm: /S10/BARCODE_EXAMPLE
ABAP
program /s10/barcode_example.
class barcode_class definition inheriting from /s10/any.
public section.
* project path (textpool, screens)
constants:
projectpath type string value 'sap/bc/bsp/s10/barcode'.
data:
vbeln type vbkok-vbeln,
posnr type vbpok-posnr_vl,
lfimg type vbpok-lfimg,
matnr type mara-matnr,
maktx type makt-maktx.
methods:
* Method to book outgoing goods
update_delivery,
* Build the description for a material
build_maktx
importing
matnr type mara-matnr
exporting
maktx type makt-maktx.
endclass.
class barcode_class implementation.
method build_maktx.
* read maktx
select single maktx from makt into maktx
where matnr = matnr and spras = sy-langu.
endmethod.
method update_delivery.
* Use a self defined authority object
authority-check object 'Z_S10_BARC'
id 'ACTVT' field '10'.
* not authorized -> message to user and stop processing
if sy-subrc <> 0.
s10errormessage(
exporting
msgid = 'CACSIB'
msgno = 503
).
endif.
data: ps_vbkok type vbkok.
data: lw_vbpok type vbpok.
data: pt_vbpok type table of vbpok.
data: lt_prot type table of prott.
data: lw_prot type prott.
clear ps_vbkok.
ps_vbkok-vbeln_vl = vbeln.
ps_vbkok-vbtyp_vl = 'J'.
ps_vbkok-wabuc = 'X'.
ps_vbkok-wadat_ist = sy-datum.
lw_vbpok-vbeln_vl = vbeln.
lw_vbpok-posnr_vl = posnr.
lw_vbpok-lfimg = lfimg.
lw_vbpok-umvkz = 1.
lw_vbpok-umvkn = 1.
append lw_vbpok to pt_vbpok. clear lw_vbpok.
call function 'WS_DELIVERY_UPDATE_2'
exporting
vbkok_wa = ps_vbkok
synchron = 'X'
commit = 'X'
delivery = vbeln
if_error_messages_send = 'X'
tables
vbpok_tab = pt_vbpok
prot = lt_prot
exceptions
error_message = 4
others = 2.
if sy-subrc = 0.
s10infomessage( s10localize( id = 'booking_success' ) ).
endif.
* Error occured
if sy-subrc <> 0.
s10errormessage(
exporting
msgid = sy-msgid
msgno = sy-msgno
).
endif.
* Error messages ?
loop at lt_prot into lw_prot where msgty = 'E' or msgty = 'A'.
data: msgno type syst_msgno.
msgno = lw_prot-msgno.
s10errormessage(
exporting
msgid = lw_prot-msgid
msgno = msgno
).
endloop.
endmethod.
endclass.
* main class for this application
class main definition inheriting from /s10/any.
public section.
data: mybarcode_class type ref to barcode_class.
methods:
logon.
endclass.
class main implementation.
* logon user
method logon.
* set S10 license
s10setlicense( 'Synactive GmbH demo license number=100 role=s10demo_role
maxusers=10 signature=821.126.87.7' ).
* create manager object
create object mybarcode_class.
* start list display
mybarcode_class->s10nextscreen( 'start').
endmethod.
endclass.